9. 進階使用表單及對話方塊
表單的標準用法
在
第二章 我們已經講解了許多有關表單的屬性、方法、及事件。在這一章，我們將說明如何將物件導向程式設計應用在表單上，教您如何利用這個技巧來寫出有效率、沒有錯誤(Bug-Free)的程式。
把表單當作物件
首先，我們必需瞭解在Visual Basic中，什麼是表單。事實上，從版本4.0以後，表單就是一個物件模組加上一個設計師(Designer)。您可以回想第二章所講的，設計師是一個整合的發展環境模組，可以讓程式設計人員利用視覺化的界面去設定物件執行時期的的屬性。
利用表單設計師，您可藉由拖拉控制項，設定表單上控制項的各種屬性，讓您在設計時期，去定義一個表單的外觀。當應用程式執行時，Visual Basic即時的把這些資訊轉譯成對應的Window API來產生主視窗，以及那些在上面的控制項。而一個典型的Visual Basic控制項，要轉譯成相對應的C或C++程式碼，可能都要長達好幾百行，或許您已經瞭解為什麼Visual Basic能在短時間內成為設計Window程式最受歡迎的語言。
我們可以很容易地證明表單只是一個具有使用者介面的物件。假設在您的應用程式中有一個叫做 frnDetails 的表單，您可以利用物件的New方法來產生一個物件實體：
Dim frm As frmDetails Set frm = New frmDetails frm.Show
要證明表單是一個物件，很重要的一點，就是要像一般物件具有屬性、方法、及事件。舉例來說，您可新增一個甚至多個的Public屬性，將表單上的控制項做封裝，請看底下這段程式：
' Inside the frmDetails form
Public Property Get Total() As Currency
Total = CCur(txtTotal.Text)
End Property
相同地，您也可新增一些Pulbic 的方法，讓主程式能夠透過呼叫這些方法，來讓表單完成一些工作，例如讓它列印出自己的內容：
' Note that Sub, Function, and Property procs are Public by default.
Sub PrintOrders()
' Here you place the code that prints the form's contents.
End Sub
在表單模組外，您可以像一般的物件一樣取得它的屬性：
Dim Total As Currency Total = frm.Total() frm.PrintOrders
表單與一般物件最重要的不同點是表單不能被宣告成Public，讓其它的應用程式透過COM的方式來存取。
在表單中隱藏的全域變數
很矛盾地，就像我們知道要使用物件前必須先要啟始(initialize)它，對此而言，我們必需把表單看做是一個「特殊」型態的物件。因為您可以直接使用一個表單，而不用先做啟始的動作。例如在下面的程式片段，您不用先明確的建立frmDrails 表單：
Private Sub cmdDetails_Click()
frmDetails.Show
End Sub
既然我們說表單是一個物件，為什麼上面的程式不會產生error 91: "Object variable or With block variable not set"？其實這個問題已經存在一段時間了。當版本4.0發表時，微軟工程師必需確保在版本3.0，甚至之前版本發展的程式，能夠在新版本上正確地執行。簡單的說，若在版本3.0所開發的專案，無法在版本4.0上使用，那版本4.0便是一個失敗的版本。於是工程師們想出一個既簡單又優雅的解決方法。在目前的應用程式中，編譯程式產生了一個與表單相同名稱的全域變數，而這個變數是隱藏起來的：
' (Note: you will never actually see these declarations.) Public frmDetails As New frmDetails Public frmOrders As New frmOrders ' (Same for every other form in the application)
當您的程式碼參考到這個表單的實體時，並不是直接引用到fmDetail的表單物件，而是引用到與這個表單同名的全域變數。正因為這個變數是自動產生的，Visual Basic在您引用到這個變數時，立刻會建立新的表單物件。這個利用隱藏全域變數的聰明技巧，成功的讓程式發展人員能夠輕鬆的把在版本3.0中發展的程式，使用在版本4.0或更新的版本上。但是，稍後您也會看到這些隱藏的變數會造成潛在的問題，這是您必須要注意的。
清除表單實體的問題
為了描述這個已被證明常在使用表單上碰到的問題，我們建立一個簡單的frmLogin表單，它會重覆詢問使用者姓名及密碼，直到兩者都正確為止。這個表單擁有兩個Public的屬性， UserName及Password，它們會在 Unload 事件中，分別被指定為在txtUserName及txtPassword控制項的值：
Public UserName As String
Public Password As String
Private Sub cmdOK_Click()
' Unload this form only if password is OK.
If LCase$(txtPassword) = "balena" Then Unload Me
End Sub
Private Sub Form_Load()
' Move property values into form fields.
txtUserName = UserName
txtPassword = Password
End Sub
Private Sub Form_Unload(Cancel As Integer)
' Move field contents back into public properties.
UserName = txtUserName
Password = txtPassword
End Sub
您可以讓frmLogin表單顯示出使用者所輸入的值：
' Code in frmMain form Private Sub cmdShowLogin_Click() frmLogin.Show vbModal ' Execution gets here only if password is OK. MsgBox frmLogin.UserName & " logged in." End Sub
要測試表單是否正常運作，先執行主表單，點選cmdShowLogin按鍵，然後輸入使用者名稱及密碼(如圖9-1)。當frmMain主表單再度取得控制權時，它會顯示一個訊息對話方塊。表面上似乎一切運作正常，假如您再次按下Login按鈕，frmLogin表單將再被帶出，但是這一次，之前使用者的名稱及密碼卻會直接顯示在表單上。這可不是我們所希望的保密方式！
| 圖9-1 Login 範例程式 |
要瞭解問題發生在哪裡，請把下面這段程式碼加入表單模組中：
Private Sub Form_Initialize()
Debug.Print "Initialize event"
End Sub
Private Sub Form_Terminate()
Debug.Print "Terminate event"
End Sub
現在，假如您重覆地依照我們剛才的步驟去執行程式，您會發現，在程式參考到 frmLogin 的時候會立刻發生 Initialize 事件，反之，Terminate 事件卻從未發生。換句話說，您第二次所顯示的frmLogin表單，是在您第一次執行時所建立的實體。這個表單被正常的Unload，但Visual Basic卻沒有釋放表單實體的資料區(Data area)，也就是說，不管是Private或Public變數，都仍然存在於記憶體中。因為這個原因，第一次輸入的使用者姓名及密碼會永遠存在於記憶體中，就像兩個TextBox控制項中所顯示的。在真正開發應用程式時，這個特性將可能造成一些很難被發現的錯誤，因為這種類型的錯誤於使用者介面上是看不到的。
要讓上面的程式正常運作，可以強迫Visual Basic釋放舊的表單實體以確保下次會再建立一個全新的實體。有兩個方法可以來達成，最常用的就是在Show方法後，把表單變數設為Nothing：
Private Sub cmdShowLogin_Click()
frmLogin.Show vbModal
MsgBox frmLogin.UserName & " logged in."
' Set the hidden global form variable to Nothing.
Set frmLogin = Nothing
End Sub
另外就是使用比較類似物件導向觀念的方式。您只要簡單的宣告一個與表單名稱相同的區域變數，這樣便能取代全域變數：
Private Sub cmdShowLogin_Click()
Dim frmLogin As New frmLogin
frmLogin.Show vbModal
MsgBox frmLogin.UserName & " logged in."
End Sub
現在您執行這支程式，將會發現Visual Basic已經正確的發生 Form_Terminate 的事件，因此我們可以確認表單已經被完全釋放。從這個技巧，可以發現有趣的一點，您可以一次同時建立多個表單實體，如圖 9-2。
Private Sub cmdShowDocument_Click()
Dim TextBrowser As New TextBrowser
TextBrowser.Filename = txtFilename.Text
' Show the form, making it a child form of this one.
TextBrowser.Show, Me
End Sub
| 圖9-2 使用明確的表單變數，您可以建立並顯示多個相同的表單實體。所有的子表單都會顯示在父表單的上層，即使父表單已經得到駐點(focus) 。 |
小秘訣
表單 Show 方法提供了第二個選擇項引數，讓您指定所顯示表單的父表單為何。當您傳入值到這個引數，會發生兩件有趣的事情：子表單一定顯示在父表單的上層，即使父表單已經獲得駐點。其次，當父表單關閉或最小化時，子表單也自動的關閉或最小化。您可以利用這個特性建立一個可擺工具列、調色盤或是一組圖示等的浮動式子表單。此時您可將子表單 BorderStyle 設為4-Fixed ToolWindow 或是5-Sizable ToolWindow。
您可以在隨書CD中找到完整的frmTextBrowser表單模組的程式碼。請注意這個例子都是使用非獨佔式的表單。
當表單變數的生命週期結束後，您仍然可以看到它的畫面，此時Visual Basic不會釋放表單的資料區。直到使用者Unload這個表單，Visual Basic在 Form_Unload 事件後，立刻觸發 Form_Terminate 的事件，此時，資料區才會被釋放。這個特性好像違反了「當物件不再被引用時，就應該被銷毀」的規則，接下來筆者將說明事實上，我們並不是完全不再參照這個表單。
表單集合
表單集合(Forms collection) 是一個全域性的集合，它包含所有已經被載入的表單。也就是說所有已經被載入的表單都會被這個集合引用到，因此就算程式中已不再有任何對表單的引用，它們依然不會被釋放。透過底下的函式，您可以從表單集合取得對任何一個表單的引用(reference)：
Function GetForm(formName As String) As Form
Dim frm As Form
For Each frm In Forms
If StrComp(frm.Name, formName, vbTextCompare) = 0 Then
Set GetForm = frm
Exit Function
End If
Next
End Function
假如在集合中有相同名稱的表單，則傳回名稱相符合的第一個，您可以用底下的程式，透過表單的名稱來取得該表單的引用：
GetForm("frmLogin").Caption = "Login Form"
您可能需要注意的是，GetForm 函數所傳回的是form的型態。也就是傳回的表單只能使用到一般form應有的方法及屬性，例如 Caption 及 ForeColor 屬性或是 Move 與 Show 的方法，若您要使用自訂的屬性或方法，您必需定義一個指到某一特定表單物件的變數，再把 GetForm 傳回的表單轉型(Cast)存到該變數中：
Dim frm As frmLogin
Set frm = GetForm("frmLogin") = "Login Form"
username = frm.UserName
可重複使用的表單
就像物件模組一樣，若把表單當成是一個物件，那就應該具有可重覆使用的特性。可重覆使用的表單可以應用到很多地方，最簡單的就是我們在 第二章 所講的，把表單當作是一個樣版。然而若再稍加一點技巧，我們將可設計出更具彈性、可用性的表單物件。在下面的幾節中，我們將更進一步描述這些技巧。
使用自訂的屬性及方法
很多商業應用程式會顯示出日曆讓使用者在上面直接選擇日期。Visual Basic也提供一個MonthView Micsrosoft ActiveX控制項(請看 第11章 )，但是若使用自己設計的表單則可以有以下幾點好處：舉例來說，可以讓我們自訂大小(size)、日期的顯示方式以及代表假日的顏色等等。一般來說，在使用者介面上使用自訂的表單可以帶來最大的彈性，在隨書光碟中，您可以取得圖9-3中frmCalendar表單的完整的程式碼。這些日期的按鈕，是一組由名為OptionButton的控制項陣列所排列而成的，每個按鈕的Style屬性都設為1-Graphical。
| 圖9-3 自訂的日曆表單，透過自訂的屬性，方法及事件與主程式做溝通。 |
frmCalendar 提供幾個屬性讓您自訂它的介面，例如 DialogTitle (設定對話方塊的標題)、FirstDayOfWeek 及 SaturdayIsHoliday (在設定日曆外觀很有用)。也提供一組屬性來取得使用者所選擇的日期：CancelPressed (當使用者未做任何選擇時傳回True)、SelectedDate (可讀寫日期)、Day、Month及Year (唯讀，可傳回所選擇的日、月、年)。這個模組只有一個名為 ShowMonth 的方法，它可以依據所傳入的月份，顯示出該月份的日曆，也可以將某一特定的日期做標記：
Private Sub cmdCalendar_Click()
Dim Calendar As New frmCalendar
Calendar.DialogTitle = "Select a new date for the appointment"
' Highlight the current day/month/year.
Calendar.ShowMonth Year(Now), Month(Now), Day(Now)
' Show the calendar as a modal dialog.
Calendar.Show vbModal
' Get the result if the user didn't press Cancel.
If Not Calendar.CancelPressed Then
AppointmentDate = Calendar.SelectedDate
End If
End Sub
一般而言，要把表單當成一個物件使用，那就應該提供一組介面讓使用者來存取表單的原生(native)屬性。例如，frmCalendar 表單模組提供一個 DialogTitle 的自訂屬性，來取代原本表單的 Caption 屬性。使用這個方法，用戶端就不會破壞表單物件的封裝(encapsulation)，讓您確保物件內部的正確運作。很遺憾地，在表單物件中，您沒有辦法去避免其它應用程式直接呼叫表單或表單上控制項的原生屬性，或許這就是享受表單物件所帶來的好處時同時需付出的代價吧。
增加自訂的事件
在上面的程式碼中，frmCalender表單是以獨佔式的方式顯示對話方塊，也就是程式一直要等到對話方塊被關閉後，才會繼續執行下去。當對話方塊關閉時，接下來的程式碼就會檢查表單的屬性，取得使用者選擇日期。然而，在大多數情況下，您可能須要使用非獨佔式的方式來顯示對話方塊。此時，您必需學習一個方法來得知使用者何時關閉對話方塊，然後才去查詢 SelectedDate 屬性。您可以藉由新增一對自訂的事件來達到上述的目的：
Event DateChanged(newDate As Date) Event Unload(CancelPressed As Boolean)
自訂事件增加了frmCalendar模組的可用性。就像一般的物件一樣，要捕捉這些事件，您必須在顯示日曆對話方塊的模組階層(module-level)增加一個 WithEvents 變數：
' In the frmMain form
Dim WithEvents Calendar As New frmCalendar
Private Sub cmdCalendar_Click()
Set Calendar = New frmCalendar
Calendar.DialogTitle = "Select a new date for the appointment"
Calendar.ShowMonth Year(Now), Month(Now), Day(Now)
Calendar.Show ' Show as a modeless dialog box.
End Sub
Private Sub Calendar_DateChanged(newDate As Date)
' Show the date currently selected on a Label control.
lblStatus.Caption = Format(newDate, "Long Date")
End Sub
Private Sub Calendar_Unload(CancelPressed As Boolean)
If CancelPressed Then
MsgBox "Command canceled", vbInformation
Else
MsgBox "Selected date: " & Format$(Calendar.SelectedDate, _
"Long Date"), vbInformation
End If
' We don't need this variable any longer.
Set Calendar = Nothing
End Sub
說明
讀者可能會問為什麼需要一個自訂的 Unload 事件，您可能以為當變數Calendar 引用frmCalendar表單時，也一樣可以捕捉frmCalendar的 Unload 事件。這個假設並不正確，事實上，Calenader 變數只是單純指向frmCalendar的自訂介面而已。像標準表單所具備的 Unload、Resize、Load、Paint 等事件，並不能藉由型態為 frmCalendar 的變數所捕捉。要能捕捉這些事件，就必須要宣告一個型別為 Form 的變數，在這個例子中，我們使用自訂的 Unload 事件，實作將會比較簡化。
就像一般的標準物件模組一樣，使用自訂的事件，將會為表單模組帶來更多的彈性。增加一個Change-Like的事件，就像在frmCalendar模組中的 DataChanged 事件，可讓使用者彼此間的日期保持一致。您也可自訂一個 Progress 事件，當程式處理時間過長時，可用來顯示進度，有關事件的使用，請參考 第七章 。
參數化的表單
一個表單在執行時期提供一組方法及屬性，可以讓主程式用來決定表單顯示的外觀，我們稱之為參數化的表單，透過參數化可以讓表單更具重覆使用性。請看圖9-4可以更瞭解筆者的意思﹔圖中兩個具有選項按鈕的表單，實際上是相同的表單模組，它們依據主程式的需要，而顯示不同的外觀。
參數化的表單製作上比較困難，首先，您必須定義出一組方法及屬性來讓使用者決定顯示表單的外觀。其次，您可能要寫很長的程式碼來讓表單上所有的控制項能夠在執行時期，自動將自己顯示於畫面正確的位置上。
frmOptions表單提供三個關鍵方法讓您新增框架(Frame Control)、核取方塊(CheckBox Control)及選項按鈕(OptionButton)控制項：
Private Sub cdmOptionsOne_Click()
Dim frm As New frmOptions
' Add a Frame control _ the first argument to this and following
' methods is a unique ID code for the control being created.
frm.AddFrame "F1", "First Group"
' Each subsequent AddOption and AddCheck method adds
' a control inside the current frame, until another AddFrame
' method is issued.
frm.AddOption "O1", "&1. First", True ' Set the value to True.
frm.AddOption "O2", "&2. Second"
frm.AddOption "O3", "&3. Third"
' Add a second frame, with three radio buttons and two check boxes.
frm.AddFrame "F2", "Second Group"
frm.AddOption "O4", "&4. Fourth", True ' Set the value to True.
frm.AddOption "O5", "&5. Fifth"
frm.AddOption "O6", "&6. Sixth"
' Tick this check box control.
frm.AddCheck "C1", "&7. Check one", True
frm.AddCheck "C2", "&8. Check two"
' Show the form as a modal dialog.
frm.Show vbModal
frmOptions表單模組的 Value 方法會傳回控制項的ID值。您可以使用ID值來取得CheckBox或是OptionButtons的 Value 值，也可以知道OptionButton控制項是否被選取：
' Continuing the cmdOptionsOne_Click procedure...
If frm.CancelPressed Then
MsgBox "Command canceled", vbInformation
Else
MsgBox "Option button in first frame: " & frm.Value("F1") _
& vbCr & "Option button in second frame: " _
& frm.Value("F2") & vbCr _
& "First checkbox : " & frm.Value("C1") & vbCr _
& "Second checkbox: " & frm.Value("C2") & vbCr, _
vbInformation, "Result of Options form"
End If
End Sub
請參考原始碼，看看frmOptions表單中的框架(Frame)改變大小(Resize)時，如何重新排列所包含的控制項。也可看到當表單改變大小時，如何一併改變框架的大小。您可以建立很多像frmOptions的參數化表單，例如建立具有很多種按鈕、圖示、字型的訊息方塊。參數化的表單最大的好處在於其可以重複使用性，縱使顯示外觀不同，但其使用方法都是相同的。這種技巧可以節省EXE檔案的大小及執行時所須的記憶體。
把表單當作物件瀏覽器
您可以把表單作另一種運用。假如您的應用程式廣泛使用物件模組來儲存、處理資料，您可能需要一個特殊的資料物件瀏覽器。舉例來說，假如您使用一個名為Cperson的物件模組來存放個人資料，您可以建立一個frmPerson表單模組，它具有一個型態為Cperson的Person屬性。這樣可大幅簡化用戶端的程式，因為它只要指定一個物件，而不需指定各種不同的屬性 (如本例中的 Name、Address、City及Married )：
' The client code that uses the frmPerson form Dim Person1 As New CPerson ' Initialize properties for this instance. Person1.Name = "John Smith" Person1.Address = "12345 West Road" ... ' Display it on screen. Dim frm As New frmPerson Set frm.Person = Person1 frm.Show
frmPerson表單必須正確的把 Person 屬性指定給對應的欄位，如圖9-5及以下的程式碼。
| 圖9-5 使用表單來當作物件瀏覽器。這兩個表單實體顯示同一個Cperson物件，並且會自動同步化。 |
' Inside the frmPerson form module
Private WithEvents ThisPerson As CPerson
Property Get Person() As CPerson
Set Person = ThisPerson
End Property
Property Set Person(newValue As CPerson)
' Initialize the private object and form fields.
Set ThisPerson = newValue
With ThisPerson
txtName.Text = .Name
txtAddress.Text = .Address
txtCity.Text = .City
chkMarried.Value = Abs(.Married) ' Assign zero or one.
End With
End Property
使用這種技巧另一個好處就是用戶端的程式不會直接對Cperson物件的屬性做存取。當物件模組的介面改變時，您必須在frmPerson模組新增或移除陳述式(statements)，但是不需要修改用戶端的程式.。
更妙的好處是：當表單直接與物件連結時，表單可以取代物件本身對資料的驗證工作，在設計物件導向的應用程式中，這是正確的觀念。驗證的工作通常發生在使用者按下OK按鈕時：
' In the frmPerson form module...
Private Sub cmdOK_Click()
On Error Resume Next
' Assign (and implicitly validate) the Name property.
ThisPerson.Name = txtName.Text
If Err Then
' If the class raised an error
MsgBox Err.Description
txtName.SetFocus
Exit Sub
End If
' Similar code for the Address, City, and Married properties.
...
End Sub
使用表單來瀏覽物件還有第四點好處，在筆者看來是最重要且最具有技術的一點。既然每個表單都有一個對物件的引用，我們可以產生多個表單指向同一個物件。雖然每個表單存取相同的資料，卻能於顯示時具備一致性。請執行ObjView.Vbp專案，就可瞭解筆者所要表達的。在John Smith按鈕按下兩次以上，並更改表單中的資料，再點選OK按鈕，可發現其它的表單中的值也被自動的更新。藉由在主表單中Notification frame選擇不同的選項，您也可以設定在使用者離開欄位甚至每按下一個鍵時，更新其它表單上的值。在範例程式中，筆者增加這些功能只是為了證明這些功能可以被實作。
要實作第四點，當Cperson物件的屬性被更改時，要引發一個事件：
' In the CPerson class module...
Event Change(PropertyName As String)
' A private variable that holds the value of the Name property
Private m_Name As String
Property Let Name(newValue As String)
' It's very important that the new value always be checked.
If newValue = "" Then Err.Raise 5, , "Invalid Value for Name property"
If m_Name <> newValue Then
m_Name = newValue
PropertyChanged "Name"
End If
End Property
' Similar code for Property Let Address/City/Married
...
' This private method simply raises a Change event in client code.
Private Sub PropertyChanged(PropertyName As String)
RaiseEvent Change(PropertyName)
End Sub
在frmPerson表單模組中，ThisPerson 變數指到Cperson物件，且使用WithEvent 關鍵字，因此可以捕捉Cperson的 Change 事件：
Private Sub ThisPerson_Change(PropertyName As String)
Select Case PropertyName
Case "Name"
txtName.Text = ThisPerson.Name
Case "Address"
txtAddress.Text = ThisPerson.Address
Case "City"
txtCity.Text = ThisPerson.City
Case "Married"
chkMarried.Value = Abs(ThisPerson.Married)
End Select
End Sub
當把表單當作物件瀏覽器來使用時，有兩點必須注意的：
' Inside the frmPersonalData form module...
Private PersData As IPersonalData
Property Get PersonalData() As IPersonalData
Set PersonalData = PersData
End Property
Property Set PersonalData(newValue As IPersonalData)
Set PersData = newValue
' Initialize fields on the form.
With PersData
txtName = .Name
...
End With
End Property
同樣的，您不能透過第二種介面來捕捉這些物件的事件，所以，只有您不需要讓表單上的資料自動同步更新時，才可使用這個作法。
但當您使用強制回應式(modal)表單時，就不用顧慮到資料同步的問題了。
動態新增控制項
在Visual Basic 6中新增加的動態新增控制項功能，是令大家很期待的，因為在之前的版本，程式因為不具這項功能而受到很大的限制。這項功能可以讓您在執行時期使用類別名稱(Class name)來新增控制項。這個機制比使用控制項陣列(control array)還具彈性(請參考
第三章 )，事實上，使用控制項陣列時，強迫您在設計時期就必需先放上您要動態增加控制項的實體，相反地，透過Visual Basic 6中動態新增控制項功能就不需這個動作。
控制項集合(Controls collection)的Add方法
在Visual Basic6中，控制項集合提供 Add 方法可以讓您在執行時期動態新增控制項，底下是 Add 方法的語法:
Set controlRef=Controls.Add(ProgID，Name [,Container])
ProgID是指控制項的類別名稱，它是 Libraryname.controlname 的格式。Name 是您給控制項的名稱， (這就是控制項Name屬性所傳回名稱) 。Name 必需為唯一的(unique)，假如在集合中有其它的控制項具有同樣的名稱，就會產生Error 727 "There is already a control with the name 'ctrlname'" 。Container 為選擇性參數，是一個對收納器控制項(如PictureBox 或是Frame控制項)的引用，如果沒有指定或為 NULL，預設值為Controls 集合物件所屬的收納器。ControlRef 為物件變數，是一個對該控制項的引用，透過此變數可使用控制項的屬性，方法及事件，由底下的程式碼您可以發現要在表單右下角，動態新增一個 CommandButton 控制項，是非常容易的一件事。
Dim WithEvents cmdCalendar As CommandButton
Private Sub Form_Load()
Set cmdCalendar = Controls.Add("VB.CommandButton", "cmdButton")
' Assumes that form's ScaleMode is twips.
cmdCalendar.Move ScaleWidth - 1400, ScaleHeight - 800, 1000, 600
cmdCalendar.Caption = "&Calendar"
' All controls are created invisible.
cmdCalendar.Visible = True
End Sub
在 cmdCalendar 中使用到 WithEvents 變數可以讓您對它的事件作處理，例如您可以在使用者按下動態新增的按鈕時顯示出一個自訂的日曆：
Private Sub cmdCalendar_Click()
Dim frm As New frmCalendar
frm.ShowMonth Year(Now), Month(Now)
frm.Show vbModal
End Sub
您也可使用 Remove 方法來移除已經動態增加的控制項，它只有一個參數：控制項的名稱，(就是 Add 方法的第二個參數):
Controls.Remove "cmdButton"
假如您試圖移除一個不是在執行時期動態新增的控制項，將會發生錯誤。
動態新增外部的ActiveX 控制項
新增外部ActiveX 控制項方式跟新增Visual Basic內建控制項有點像，
但是有兩點細節您必需注意：
| 圖9-6 當您要使用由物件瀏覽器找到的ProgID字串來建立TreeView控制項時，會得到這個錯誤訊息。 |
| 圖9-7 當您試圖要載入一個出現在工具箱(toolbox)中的ActiveX控制項，但是它卻未被同一應用程式引用過時，會得到這個錯誤訊息。 |
說明
您可以動態新增除了Menu Items以外所有Visual Basic內建的控制項，不幸的是，這個限制讓程式設計師在執行時期無法動態更改選單結構。
非視窗控制項程式庫
Visual Basic 6新增加了一個非視窗控制項程式庫，這些控制項不論外觀及特性幾乎都跟Visual Basic內建的控制項沒兩樣。Visual Basic文件本身並沒有提到這個程式庫，因此您必需自己由Common\Tools\Visual Basic\Winless 目錄中來安裝。這個目錄包含一個 Mswless.ocx ActionX控制項，以及一份檔名為Ltwtct98.chm 的說明文件。要使用這個程式庫，您必需先將該目錄複製到硬碟裏，使用之前您必須利用Regsvr32.exe 來將它註冊到系統，或是在Visual Basic中double-click Mswless.reg檔案，這會產生能讓Visual Basic環境，使用這個控制項的機碼。
一旦您完成註冊程序，您便可在發展環境下按 Ctrl+T 鍵，選取Microsoft Windowless Controls 6 項目，然後您會發現工具箱中又多了幾個控制項
這個程式庫提供了TextBox、Frame、CommandButton、CheckBox、OptionButton、ComboBox、ListBox，以及兩個 ScrollBar的控制項，它並未提供Label、Timer、或Image控制項，因為在Visual Basic本身中，這些控制項本來就是非視窗(windowless)的。另外它也未包含PictureBox 及OLE 控制項，這是因為這兩者是收納器，因此不會有非視窗的版本。非視窗的控制項不提供 hWnd 屬性，請回憶在 第二章 所提及的 hWnd 屬性，這個屬性是讓Window識別控制項用的，既然非視窗控制項，那hWnd 就沒有意義了， 另外它也省略了一些用來在DDE溝通用的屬性(DDE 技術已經過時了，本書將不探討) 。另外一個不同點是，在非視窗的WLOption 控制項(與Visual Basic內建的OptionButton相對應)中，提供新的 Group 屬性，可以在表單中自訂幾個不同群組，讓在相同群組內的 Radio 按鈕互斥 (您不可以利用將Raio按鈕放在 WLFrame上來達到互斥，因為WLFrame 控制項不是一個收納器) 。
除了 hWnd 及 Group 屬性外，在這個程式庫中的控制項都完美地與Visual Basic內建的控制項相容，有同樣的屬性、方法、事件。有趣地是，這個程式庫中的控制項都提供屬性頁(property page) ，讓程式設計師更輕鬆的設定每個控制項的屬性，如圖9-8。
| 圖9-8 您可以使用屬性頁來設定在非視窗程式庫中的控制項，請注意出現在工具箱的新控制項。 |
使用非視窗控制項的好處是在執行時不用像Visual Basic內建控制項一樣受到許多限制。事實上非視窗控制項所有的屬性都可在執行時期更改，如WLText控制項的 Multiline 及 ScrollBars 屬性、WLList及WLCombo控制項的Sorted及 Style 屬性、WLCheck及WLOption控制項的 Alignment 屬性。
這種可在執行時期設定屬性的能力，在動態新增控制項時非常重要(使用Controls.Add 方法)，當您動態新增控制項，它們的屬性會被設定為內定(default) 值，這代表當您要動態新增Visual Basic內建的控制項，如TextBox，您不能改變 multiline 屬性，或是更改ListBox、ComboBox的 Sort 屬性，相對地，這只有輕量控制項能達到：
Dim WithEvents TxtEditor As MSWLess.WLText
Private Sub Form_Load()
Set TxtEditor = Controls.Add("MSWLess.WLText", "txtEditor")
TxtEditor.MultiLine = True
TxtEditor.ScrollBars = vbBoth
TxtEditor.Move 0, 0, ScaleWidth, ScaleHeight
TxtEditor.Visible = True
End Sub
未引用的控制項
到目前為止，筆者所講的都是那些設計時期就已經在工具箱引用的控制項，但透過建立動態控制項特點，建立未被工具箱引用的ActiveX控制項，您可以發揮更大的功能。
您可以設計出支援不同版本ActiveX控制項的應用程式，例如當新的控制項發佈時，只要更改存在INI檔案裏控制項的名稱就可以了。當您要把表單轉成ActiveX 控制項收納器，這個功能提供更大的彈性。
首先，您必須解決那些在設計時期未出現在工具箱的控制項授權問題。即使您實際上沒在設計時期使用到該控制項，您仍必須證明在執行時期動態載入該控制項是合法的。如果在執行時期，對動態載入ActiveX控制項沒做任何限制，那任何一個程式設計師都可以任意向商業軟體「借」ActiveX 控制項來使用，而不用花錢去購買授權。這個問題只出現在執行時期未引用在工具箱的控制項上，若您可以把控制項載入到工具箱，那您就具有了設計時期的授權。
要在執行時期動態新增一個未引用在工具箱的ActiveX控制項，在編譯時您必須提出您的設計時期授權。這裏的授權是指當您在機器上安裝控制項時，在系統Registry中產生一個由文字及數字組合而成的字串。Visual Basic不強迫您一定要在Registry搜尋這個字串，因為您可以透過Licenses 集合物件的Add方法來達成：
' This statement works only if the MSWLess library is
' *NOT* currently referenced in the Toolbox.
Dim licenseKey As String
licenseKey = Licenses.Add("MSWLess.WLText")
當您取得授權資料(license string)，您必須想出一個方法讓執行時期可以使用，最簡單的方式就是把它存放在檔案中：
Open "MSWLess.lic" For Output As #1 Print #1, licenseKey Close #1
之前的程式碼只有在設計過程會使用到，一旦產生了LIC檔案，您就不會再使用到了。應用程式執行時會利用Licenses 集合物件另一個不同語法的 Add 方法：
Open "MSWLess.lic" For Input As #1 Line Input #1, licenseKey Close #1 Licenses.Add "MSWLess.WLText", licenseKey
Licenses集合物件也提供 Remove 方法，但您應該不會使用到它。
後期連結的屬性、方法及事件
當您解決了授權的問題，接下來您必須面對編譯未被引用在工具箱的ActiveX控制項會產生的問題。正如您想像的，假使您不知道在執行時期會載入哪個控制項，就無法指定正確型態給 Controls.Add 方法所傳回的變數。這意指您沒有簡單的方法去存取新增控制項的屬性、方法及事件。
Visual Basic 6所提供的解決辦法是一個特別的物件變數 vbControlExtender，這是一個Visual Basic整合發展環境的ActiveX控制項：
Dim WithEvents TxtEditor As VBControlExtender
Private Sub Form_Load()
' Add the license key to the Licenses collection (omitted).
Set TxtEditor = Controls.Add("MSWLess.WLText", "TxtEditor")
TxtEditor.Move 0, 0, ScaleWidth, ScaleHeight
TxtEditor.Visible = True
TxtEditor.Text = " My Text Editor"
End Sub
要捕捉未被引用在工具箱的ActiveX控制項的事件，比存取它的屬性或方法要來的難。vbControlExtender並不會把新控制項的事件提供給使用者，相反的，它只有一個名為 ObjectEvent 的事件，這個事件的作用，是對動態新增的控制項所發出之所有事件進行解析。ObjectEvent 接收一個參數，一個包含EventParameter物件集合的EventInfo物件。這個集合可讓程式設計師取得傳遞給事件的參數。
通常我們會在 ObjectEvent 事件程序中，檢查 EventInfo.Name 屬性來辦識是哪一個事件被觸發，我們也可以讀取，甚至更改所傳入的參數：
Private Sub TxtEditor_ObjectEvent(Info As EventInfo)
Select Case Info.Name
Case "KeyPress"
' The Escape key clears the editor.
If Info.EventParameters("KeyAscii") = 27 Then
TxtEditor.Object.Text = ""
End If
Case "DblClick"
' Just to prove that we can trap any event
MsgBox isWhy have you double-clicked me?"
End Select
End Sub
用這種事件捕捉方式，筆者稱之為後期連結的事件。某些延伸事件(extender events)您不會使用 ObjectEvent 事件來捕捉。這些延伸事件(下面的程式片段便是一例)可當作是vbControlExtender物件的標準事件。這組事件包含 GotFocus、LostFocus、Validate、DragDrop 及 DragOver。要進一步瞭解延伸事件，請參閱 第17章 。
Private Sub TxtEditor_GotFocus()
' Highlight textbox's contents on entry.
TxtEditor.Object.SelStart = 0
TxtEditor.Object.SelLength = 9999
End Sub
資料導向(Data-Driven)的表單
動態新增物件的功能讓Visual Basic 6可以建立真正的資料導向表單。這種表單會在執行時期隨著從檔案讀進的資料或是資料庫的結構來動態更改自己的顯示外觀。想看看若我們不需再重新編譯程式會帶給我們多大的方便：
要實作資料導向的表單，我們必須先解決一個問題。既然我們不知道會有多少控制項會被動態加入到表單，要怎麼去捕捉它們的事件呢?會有這個問題是因為 WithEvents 關鍵字無法捕捉到物件陣列的事件。下面，您將會發現這個問題雖然可以被解決，但並不如想像中的簡單。然而，筆者將敘述的這個技巧不但有趣且具彈性，不只可以應用在製作資料導向的表單，也可以用來捕捉未知數目的控制項事件，這正是筆者在第七章所留下的問題。
捕捉控制項陣列的事件
要在執行時期捕捉未定數目的動態建立控制項或是物件，您必須先建立兩個支援的類別，第一個類別是集合類別，包含所有第二個類別的實體。在隨書光碟的範例程式中，這兩個類別名稱分別為 ControlItems及 ControlItem。
| 圖9-9 您需要兩個輔助的類別以及一些巧妙的程式來捕捉動態建立控制項陣列的事件。 |
底下是捕捉事件的步驟：
您可以看到，要攔截事件是要經過很長的步驟。但是您現在已經學會這些技巧，將來也可用在其他的用途。
資料庫導向 資料登記 的表單
使用動態建立控制項時機之一，就是讓表單可以隨資料庫表格或是查詢，來改變表單外觀。這在撰寫伴隨大量查詢的大規模商業軟體時非常有用，因為您不會想要為每一個查詢製作一個專用表單。這個技術會大量縮短發展時間、減少檔案大小所佔的記憶體及資源。
在隨書光碟中，您可以找到一個完整的應用程式，主表單可根據由SQL SELECT查詢所傳回的資料庫表格來動態改變欄位，如圖9-10。
| 圖9-10 所有在這個表單上的控制項，都是執行時期依據ADO recordset動態產生的，這支程式會根據不同的欄位型態，產生不同的控制項，也會對欄位做驗證的工作。 |
' The collection of controls added dynamically (module-level
' variable)
Dim WithEvents ControlItems As ControlItems
' This is the most interesting routine, which actually
' creates the controls and passes them to the ControlItems
' collection class.
Sub LoadControls(rs As ADODB.Recordset)
Dim index As Long, fieldNum As Integer
Dim field As ADODB.field
Dim ctrl As Control, ctrlItem As ControlItem, ctrlType As String
Dim Properties As Collection, CustomProperties As Collection
Dim top As Single, propItem As Variant
Dim items() As String
' Start with a fresh ControlItems collection.
Set ControlItems = New ControlItems
' Initial value for Top property
top = 100
' Add controls corresponding to fields.
' This demo program supports only a few field types.
For Each field In rs.Fields
ctrlType = """
Set Properties = New Collection
Set CustomProperties = New Collection
Select Case field.Type
Case adBoolean
ctrlType = "MSWLess.WLCheck"
Properties.Add "Caption="
Case adSmallInt ' As Integer
ctrlType = "MSWLess.WLText"
Case adInteger ' As Long
ctrlType = "MSWLess.WLText"
CustomProperties.Add "IsNumeric=-1"
CustomProperties.Add "IsInteger=-1"
Case adSingle, adDouble, adCurrency
ctrlType = "MSWLess.WLText"
CustomProperties.Add "Numeric=-1"
Case adChar, adVarChar ' As String
ctrlType = "MSWLess.WLText"
Properties.Add "Width=" & _
(field.DefinedSize * TextWidth("W"))
Case adLongVarChar ' (Memo field)
ctrlType = "MSWLess.WLText"
Properties.Add "Width=99999" ' Very large width
Properties.Add "Height=2000"
Properties.Add "Multiline=-1"
Properties.Add "ScrollBars=2" 'vbVertical
Case adDate
ctrlType = "MSWLess.WLText"
Properties.Add "Width=1000"
CustomProperties.Add iIiIsDate=-1"
Case Else
' Ignore other field data types.
End Select
' Do nothing if this field type is not supported (ctrlType="").
If ctrlType <> i>"" Then
fieldNum = fieldNum + 1
' Create the label control with database field name.
Set ctrl = Controls.Add(" VB.Label", "Label". & fieldNum)
ctrl.Move 50, top, 1800, 315
ctrl.Caption = field.Name
ctrl.UseMnemonic = False
ctrl.BorderStyle = 1
ctrl.Alignment = vbRightJustify
ctrl.Visible = True
' Create the control, and move it to the correct position.
Set ctrl = Controls.Add(ctrlType, "Field" & fieldNum)
ctrl.Move 1900, top, 2000, 315
' If the field is not updatable, lock it.
If (field.Attributes And adFldUpdatable) = 0 Then
On Error Resume Next
ctrl.Locked = True
' If the control doesn't support the Locked property,
' disable it.
If Err Then ctrl.Enabled = False
On Error GoTo 0
End If
' Set other properties of the field.
For Each propItem In Properties
' Split property's name and value.
items() = Split(propItem, "=")
CallByName ctrl, items(0), VbLet, items(1)
Next
Link it to the Data control, and make it visible.
Set ctrl.DataSource = Adodc1
ctrl.DataField = field.Name
ctrl.Visible = True
' Add this control to the ControlItems collection.
Set ctrlItem = ControlItems.Add(ctrl)
' Move the actual width into the custom Width property.
' This is used in the Form_Resize event.
ctrlItem.Properties.Add ctrl.Width, i|uWidth"
' Set its other custom properties.
For Each propItem In CustomProperties
' Split property name and value.
items() = Split(propItem, "=")
ctrlItem.Properties.Add items(1), items(0)
Next
' Increment top.
top = top + ctrl.Height + 80
End If
Next
' Force a Form_Resize event to resize longer controls.
Call Form_Resize
Adodc1.Refresh
End Sub
' A control added dynamically is asking for validation.
' Item.Control is a reference to the control.
' Item.GetProperty(propname) returns a custom property.
Private Sub ControlItems_Validate(Item As ControlItem, _
Cancel As Boolean)
If Item.GetProperty("Numeric") Then
If Not IsNumeric(Item.Control.Text) Then
MsgBox "Please enter a valid number"
Cancel = True: Exit Sub
End If
End If
If Item.GetProperty("IsInteger") Then
If CDbl(Item.Control.Text) <> Int(CDbl(Item.Control.Text)) Then
MsgBox "Please enter a valid Integer number"
Cancel = True: Exit Sub
End If
End If
If Item.GetProperty("IsDate")) Then
If Not IsDate(Item.Control.Text) Then
MsgBox "Please enter a valid date"
Cancel = True: Exit Sub
End If
End If
End Sub
很多地方可以看出 LoadControls 常式值得我們再進一步的探討。首先，為了能在執行時更改如TextBox控制項的 Multiline 屬性(例如在memo欄位時)，它使用非視窗控制項。其次，為了讓程式架構更有效率以及更具延展性，在主 Select 敘述中的 Case 子句，只是把屬性名稱及值加入到 Properties集合中：當控制項被建立時，在 For Each 迴圈中，使用 CallByName 指令來指定每個屬性。第三，LoadControls中建立一個 CustomProperties 集合來存放那些不能被直接存取的控制項屬性，包含用來驗證值的 IsNumeric、IsInteger 及 IsDate 自訂屬性。
請參照隨書光碟中的主表單，ControlItems 及 ControlItem 類別的完整程式碼。
多重文件介面表單(MDI FORMS)
MDI代表多重文件介面 (Multiple Document Inteface)，這是Microsoft Office 套裝軟體中，最常使用的使用者介面類型，包含了 Microsoft Word、Microsoft Excel及 Microsoft PowerPoint。很多應用程式也使用MDI 介面，當您的應用程式必須能在同時間處理多個文件時，那麼使用MDI 介面會是最好的選擇。
多重文件介面應用程式
只要您能充份發揮Visual Basic幾個特性，要在Visual Basic中建立MDI介面是非常容易的。要發展MDI的應用程式，必須在專案中新增一個 MDIForm 模組，除了底下幾個較特殊的性質外，MDIForm模組幾乎跟一般表單沒兩樣：
多重文件介面子表單
一個MDIForm物件包含一或多個子表單。要建立這種子表單，只要新增一個一般表單，再將它的 MDIChild 屬性設為True即可。當您做這個動作，專案總管內的圖示也會改變，如圖9-11。我們不用去設定子表單是隸屬哪個MDIForm，因為每個專案只會有一個MDIForm模組。
MDI子表單不能顯示在父MDIForm的外面，且當MDI子表單被設定為啟動(startup)表單，則它的父MDIForm會自動被載入，而且在MDI子表單為可見(visible)之前顯示。除了啟動表單外，其餘的子表單都是使用New關鍵字來建立實體：
' Inside the MDIForm module
Private Sub mnuFileNew_Click()
Dim frmDoc As New frmDocument
frmDoc.Show
End Sub
MDIForm模組提供一個額外的屬性，AutoShowChildren。當我們把這個屬性設為True (內定值)，MDI子表單會在父MDIForm載入時立刻被顯示。換句話說，除非把值設為False，否則不能讓子表單在載入時不要顯示在畫面上。
MDI子表單同樣也有特殊的性質。舉例來說，它們不像一般的表單一樣有顯示功能表：當我們對MDI子表單新增一或多個功能表，且當表單變成主動時(Active)，
在父MDIForm中，子表單功能表會取代原來的父MDIForm功能表。
因為這個原因，習慣上我們都不會讓MDI子表單包含功能表，而只定義MDIForm 模組的功能表。
| 圖9-11 在設計時期的MDI Notepad應用程式 |
當MDIForm模組上的功能表指令被呼叫時，您只需利用ActiveForm屬性，將指令應用在現在主動(Active)的MDI子表單上。下面的例子解說如何執行File功能表中的Close指令：
' In the MDI parent form
Private Sub mnuFileClose_Click()
' Close the active form, if there is one.
If Not (ActiveForm Is Nothing) Then Unload ActiveForm
End Sub
您必須隨時檢查 ActiveForm 屬性，因為有可能現階段沒有任何MDI子表單是被開啟的，這時候，ActiveForm 屬性會傳回Nothing (並不如您想像的會傳回MDIForm本身)。假使您的MDI應用程式支援不同種類的MDI子表單，您通常需要得知Active的表單是哪種類型的，例如下面的程式碼：
Private Sub mnuFilePrint_Click()
If TypeOf ActiveForm Is frmDocument Then
' Print the contents of a TextBox control.
Printer.Print ActiveForm.txtEditor.Text
Printer.EndDoc
ElseIf TypeOf ActiveForm Is frmImageViewer Then
' Print the contents of a PictureBox control.
Printer.PaintPicture ActiveForm.picImage.Picture, 0, 0
Printer.EndDoc
End If
End Sub
視窗功能表
MDIForm提供一個一般表單所沒有的方法 Arrange。這個方法可提供程式快速的排列所有的MDI子表單。您可以讓所有的MDI子表單水平並排、垂直並排、重疊顯示，或是將它們最小化，依序把圖示排在MDI父表單的下方。要達到這些目的，在建立視窗功能表時需使用四個指令：Tile Horizontally、Tile Vertically、Cascade 及 Arrange Icons。底下是程式碼：
Private Sub mnuTileHorizontally_Click()
Arrange vbTileHorizontal
End Sub
Private Sub mnuTileVertically_Click()
Arrange vbTileVertical
End Sub
Private Sub mnuCascade_Click()
Arrange vbCascade
End Sub
Private Sub mnuArrangeIcons_Click()
Arrange vbArrangeIcons
End Sub
通常我們會習慣將已經被開啟的MDI子表單名稱列在功能表中，方便使用者用滑鼠點選，快速的切換到他們所需的表單(圖9-12)。在Visual Basic中可以很容易實現這個功能：您只需勾選在功能表編輯器中功能表的WindowList選項，它們可以是在最上層，或是在副功能表顯示清單。需要注意的是不管您是選擇哪一種，只能有一個功能表項目的WindowList選項可以被勾選。
| 圖9-12 Window功能表讓您排列所有MDI 子表單並且可以使用滑鼠快速的切換視窗。 |
在MDI子表單中新增屬性
在Visual Basic版本3中，要撰寫MDI的應用程式並不容易，您必須利用一個UDT型態的陣列來記載各MDI子表單的狀態，在各MDI子表單開啟或關閉時，您將會忙於維護這個陣列。在Visual Basic版本4後，事件變得簡單了，因為每個表單都可以支援自訂的屬性，而您可以將資料直接存放在每個MDI子表單模組中，不需要使用一個全域的UDTs陣列。
每個MDI子表單至少會有兩個典型的自訂屬性：Filename 及 IsDirty (當然，實際上的名稱可能不同)。Filename 屬性存放表單載入的資料檔案名稱，而 IsDirty 記載檔案是否被使用者更改過，傳回的是一個布林值。底下程式介紹MDI Notepad示範程式如何實作上述兩個屬性：
' Inside the frmDocument MDI child form
Public IsDirty As Boolean
Private m_FileName As String
Property Get Filename() As String
Filename = m_FileName
End Property
Property Let Filename(ByVal newValue As String)
m_FileName = newValue
' Show the filename on the form(tm)s Caption.
Caption = IIf(newValue = "", "Untitled", newValue)
End Property
Private Sub txtEditor_Change()
IsDirty = True
End Sub
有了 IsDirty 屬性，假設使用者改變了資料，您就可在關閉表單時詢問使用者要不要存檔，這個工作要在MDI 子表單的 Unload 事件中完成：
Private Sub Form_Unload(Cancel As Integer)
Dim answer As Integer
If IsDirty Then
answer = MsgBox("This document has been modified. " & vbCr _
& " Do you want to save it?", vbYesNoCancel + vbInformation)
Select Case answer
Case vbNo
' The form will unload without saving data.
Case vbYes
' Delegate to a procedure in the main MDI form.
frmMainMDI.SaveToFile Filename
Case vbCancel
' Refuse to unload the form.
Cancel = True
End Select
End If
End Sub
MDI收納器的多型(Polymorphic)
在前一節的MDI Notepad 應用程式，可以很正常的運作，但是並不能視為是一個好的物件導向設計。事實上，MDIForm 物件違反了MDI子表單的封裝性，因為它直接存取MDI子表單的txtEditor控制項屬性。雖然這只是個小缺點，但就像您所知道的，好的封裝是寫出可重覆使用、易於維護及沒有錯誤的程式(bug-free)的關鍵所在。筆者將用兩個方法來示範這個概念。
定義parent-child介面
若您不想父MDI 表單直接存取子表單的控制項，解決的方法就是定義一組介面來讓兩者做溝通。舉例說明，父MDI表單應該要求子表單自己載入、儲存檔案，而不是直接使用到子表單的 txtEditor屬性。同樣的，父MDI表單應該透過呼叫子表單的方法來要求在txtEditor控制項剪下、複製及貼上資料。父MDI表單也應該詢問子表單，哪些在功能表-編輯的命令是可使用的。
在撰寫MDI專案的經驗中，筆者整理出一個簡單的介面，可以符合一般MDI應用。程式的要求，除了 Filename 及 IsDirty 屬性外，這個介面還包含像 IsEmpty (若MDI子表單沒有任何資料，傳回True)、CanSave、CanCut、CanCopy、CanPaste 及 CanPrint 屬性、
Cut、Copy、Paste、PrintDoc、LoadFile、SaveFile 及 AskFilename(用在 FileOpen 或是 FileSave 的標準對話方塊中)。這個介面允許您在重新改寫MDI Notepad應用程式時，不會破壞MDI子表單的封裝性。例如下面這段程式碼實作了在MDI父表單功能表中檔案Save as命令：
Private Sub mnuFileSaveAs_Click()
' Ask the document to show a common dialog, and
' then save the file with the name selected by the user.
On Error Resume Next
ActiveForm.SaveFile ActiveForm.AskFilename(True)
End Sub
底下是實作PrintDoc方法的子MDI表單:
Sub PrintDoc()
Printer.NewPage
Printer.Print txtEditor.Text
Printer.EndDoc
End Sub
照例，這個程式的新版本也放在隨書光碟中，您會發現比舊版本的程式長了一點，但您將會立即看到使用新結構所帶來的好處。
說明
在示範程式中，筆者定義了一組屬性及方法。然後筆者把它們放到frmDocument MDI子表單的主介面中。因為frmMain MDI主表單是利用 ActiveForm 屬性來存取子表單，因此這個介面的屬性及方法是屬於後期連結，這代表您必須用 On Error 敘述來保護每個引用。若要做得更完美，請定義一個抽象類別當作第二介面，而在所有的MDI子表單模組都實作第二介面。
更改Client表單的實作
因為新版本的MDI父表單不會破壞MDI子表單的封裝性，您可以任意更改MDI子表單的實作方式，而不會引響到主程式。例如，您可以把Notepad改成一個MDI形式的影像瀏覽器。此時MDI子表單會放一個PictureBox控制項，而您必須實作介面所有的屬性及方法讓parent-child做溝通。利如，PrintDoc 方法現在改為：
Sub PrintDoc()
Printer.NewPage
Printer.PaintPicture picBitmap.Picture, 0, 0
Printer.EndDoc
End Sub
令人驚訝的是，只需更改少於20行的程式碼，就可以把MDI Notepad專案轉成一個影像瀏覽器。最令人興奮的一點就是您絲毫不用去更改frmMain 模組的程式。換句話說，您建立了一個可重覆使用，多型的MDI父表單！
甚至，我們只要稍微更改MDI父表單的程式，就可以讓不同型態的子表單共存於一個MDI收納器中，圖9-13是新版本的範例程式，可以同時存在文字文件及影像。考慮到額外需要的屬性及方法，您可以新增子表單的型態，或是擴充介面來解決。
| 圖9-13 您可以重覆利用frmMain MDI表單，來搭配不同功能的子表單，如小型的文書處理器或影像瀏覽器。 |
應用程式精靈
Visual Basic 6提供新版的應用程式精靈，它比Visual Basic 5提供的版本更具彈性，且與工具列精靈及表單精靈完整地整合。
在安裝Visual Basic時，就一併安裝了應用程式精靈，因此我們只要簡單的從增益集的增益功能管理員中選取即可。當您執行這個精靈，您可以選擇多重文字介面(MDI)單一文字介面(SDI)或是類似檔案總管的介面 (Windows Explorer-like) 如圖 9-14。
若您選擇多重文字介面，精靈會要求您設定功能表(圖9-15)：當您製作標準的功能表時，可能會希望使用像這麼簡單及直覺式的工具。
| 圖9-14 應用程式精靈：選擇介面類型。 |
| 圖9-15 應用程式精靈：選擇功能表。 |
下一步，利用內建的精靈來自訂工具列 (圖9-16)。這個靈巧的工具，您也可在增益集選單內找到名為Toolbar精靈。
接下來的步驟，應用程式精靈會詢問您要不要使用資源檔，以及是否要在Help選單中放入一個選項，可以讓使用者連結到您的Web站台。您也可選擇加入其它的表單到專案中，包含四種標準表單，或是您之前定義過的表單範本。最後，您可任意增加資料表單，此時，精靈會呼叫筆者在
第八章 描述的資料表單精靈。在最後一步驟，您可以決定是否要把設定值儲存在一個組態檔中，以便下一次執行應用程式精靈時可以省略上述步驟。
| 圖9-16 應用程式精靈：自訂工具列。 |
| 圖9-17應用程式精靈：加入標準表單。 |
雖然在您建立MDI應用程式時，應用程式精靈所產生的程式碼是個好的出發點，但在筆者的看法，這些程式碼還是有很多需要改進的地方。精靈所產生的MDI應用程式，存放一個包含RichTextBox控制項的簡單MDI子表單，來建立文書處理器型態的應用程式。然而，在某些場合，工具列上的按鈕並不像期望中的運作，而且所有關於設定通用對話方塊(common dialog)的程式碼，也不會自動正確產生，這是它的一些缺點。不幸地，您無法控制精靈如何產生程式碼，所以每次執行完精靈後，您還是必須手動地更改所產生的程式。
使用拖放功能 (DRAG-AND-DROP)
Visual Basic在早期的版本就有包含drag-and-drop的能力，但只有在Visual Basic 5新增了另一組屬性、方法及事件後，才有實現OLE-compliant機制及跨應用程式(cross-application)的拖放能力。
自動拖放模式
基本上，一個控制項可以是拖放動作的來源或目的。Visual Basic提供兩種拖放模式，自動模式或手動模式。在自動模式中，您只要在執行時期設定一個屬性，執行時，Visual Basic會幫您自動處理其它該做的。相反地，在手動模式下，您必須對拖曳過程中產生的一系列事件做處理，但換來的是對拖放過程更好的控制。
大多數Visual Basic內建的控制項及少數的外部ActiveX控制項都支援不同表單間的OLE-拖放。而少數的控制項只能被當作拖放作業的目的控制項。另外，只有少數的內建物件可使用自動模式。設定 OLEDragMode 屬性可以決定來源控制項在拖放作業的行為。同樣的，設定 OLEDropMode 屬性可以決定目標控制項在拖放作業的行為。表9-1簡列出內建控制項，及一些ActiveX控制項對拖放的支援程度。
| Controls | OLEDragMode | OLEDropMode |
|---|---|---|
| TextBox, PictureBox, Image, | vbManual, | vbNone, vbManual |
| RichTextBox, MaskEdBox | vbAutomatic | vbAutomatic |
| ComboBox, ListBox, DirListBox, | vbManual, | vbNone, vbManual |
| FileListBox, DBCombo, DBList, TreeView, ListView, ImageCombo, DataList, DataCombo | vbAutomatic | |
| Form, Label, Frame, | Not supported | vbNone, vbManual |
| CommandButton, DriveListBox, Data, MSFlexGrid, SSTab, TabStrip, Toolbar, StatusBar, ProgressBar Slider, Animation, UpDown, MonthView, DateTimePicker, CoolBar |
| 表 9-1 您可以依照控制項對拖放的支援程度來分類，在非視窗程式庫中的控制項，與內建控制項的支援程度一樣。 |
假使一個控制項支援自動模式的拖放，您只要將它的 OLEDragMode 或是 OLEDropMove 的屬性設為vbAutomatic。例如，若您希望程式中支援RTF文字格式的拖放，您只須放置一個RichTextBox控制項到表單上，並且把它的 OLEDragMode 及 OLEDropMode 屬性設為1-vbAutomatic。如此，您便可以從 Microsoft Word、WordPad及大多數的文書處理器中拖曳部分的文字到RichTextBox中。當然，您也可以對程式中其他的RichTextBox控制項作拖放動作，TextBox及MaskEdBox控制項也是一樣，就像您在圖9-18所看到的。
其它的控制項也支援 OLEDragMode 屬性的設定。但在某些情況下，這些自動拖放模式的動作可能不如您預期。看看可能的情況：您可以從一個可複選的項目清單(ListBox)控制項中，拖曳幾個所選擇的項目到一個允許多行文字的文字方塊(TextBox)控制項中，則這些項目會在文字方塊中以CR-LF來分隔。另一個情況是把FileListBox控制項中所選擇的項目放到其他支援這些項目的Windows 應用程式中。例如，在隨書光碟中的示範程式，您可以把DOC或TXT副檔名的項目放到Microsoft Word中。請注意一點，雖然DirListBox官方支援自動拖放模式的 OLEDragMode，實際上在操作時並不會有drag的動作。
| 圖9-18 這個程式示範您如何拖放文字或影像到另一個視窗程式。請觀察文字在RichTextBox及TextBox控制項中，轉換成不同的方式來呈現。 |
當使用自動拖放模式時，您的應用程式不會接收到任何事件，而您也無法控制拖放的過程。只有在使用滑鼠左鍵可以開始拖放作業，預設的效果是Move命令(意指資料搬移到目的物件，然後在來源控制項中刪除)。假使要執行複製的動作，您必須像在Window Explorer一樣，按滑鼠左鍵時同時按下Ctrl鍵。
手動拖放模式
雖然自動拖放模式中讓您只要簡單的在設計時期設定一些屬性，就可達到有趣的拖放效果。但很顯然地，要發揮拖放的更大威力，就必須使用手動的拖放模式。接下來您將會看到，要完成拖放的過程，不管是在來源或是目標物件，我們必須在幾個特定事件中撰寫程式。圖9-19簡單列出當使用者執行拖放時會產生的事件，您可能在後續的小節會參考到這個圖表。
| 圖9-19 所有在手動模式中會產生的事件 |
在圖9-20中的示範程式是由可作為OLE 拖放過程中來源及目標的RichTextBox控制項所組成。在表單上同樣還有一個ListBox控制項，它可讓您放置由RichTextBox控制項或是其他來源(如Microsoft word)的純文字資料。當您執行拖放動作時，ListBox控制項會掃描這段文字，把所有不重複的單字重新排序顯示給使用者。
| 圖9-20 這個示範程式將展示如何利用Visual Basic的OLE拖放能力，來建立一個能自動分析文字來找出不重覆的單字，並且按字母排序的ListBox控制項。 |
啟動拖放的動作
如果您希望能夠啟動拖放的動作，就必須把 OLEDragMode 的屬性設為 Visual BasicManual (除了RichText外，所有的控制項預設值皆為Visual BasicManual)，然後呼叫 OLEDrag 方法來開始拖曳的過程。通常我們會在 MouseDown 事件程序中呼叫：
Private Sub rtfText_MouseDown(Button As Integer, Shift As Integer, _
x As Single, y As Single)
' Start a drag operation if right button is pressed.
If Button = 2 Then rtfText.OLEDrag
End Sub
當您呼叫 OLEDrag 方法時，在來源控制項會產生一個 OLEStartDrag 事件。這個事件會接收一個DataObject 物件，以及一個 AllowEffects 參數。您可以把DataObject物件看做是一個容器，它會用來存放您想要從來源控制項傳遞到目標控制項的資料，這個動作是透過 SetData 方法來達成。這就好像您可以利用Clipboard來存放不同種類的資料，如表9-2。例如，RichTextBox控制項可以搬移、複製RTF或是純文字資料：
Private Sub rtfText_OLEStartDrag(Data As RichTextLib.DataObject, _
AllowedEffects As Long)
' Use selected text, or all text if no text is currently selected.
If rtfText.SelLength Then
Data.SetData rtfText.SelRTF, vbCFRTF
Data.SetData rtfText.SelText, vbCFText
Else
Data.SetData rtfText.TextRTF, vbCFRTF
Data.SetData rtfText.Text, vbCFText
End If
AllowedEffects = vbDropEffectMove Or vbDropEffectCopy
End Sub
| C onstant | Value | Meaning |
|---|---|---|
| vbCFText | 1 | Text |
| vbCFBitmap | 2 | Bitmap (BMP) |
| vbCFMetafile | 3 | Metafile (WMF) |
| vbCFEMetafile | 14 | Enhanced metafile (.emf) |
| vbCFDIB | 8 | Device independent bitmap (dib or bmp) |
| vbCFPalette | 9 | Color palette |
| vbCFFiles | 15 | List of files |
| vbCFRTF | -16639 | Rich Text Format (RTF) |
| 表9-2 DataObject 物件所支援的類型。 |
您必須在 AllowedEffects 參數中指定您要在拖放作業中來源元件可支援的動作。您可以指定1-vbDropEffectCopy 或是 2-vbDropEffectMove，若您需要同時支援兩個動作，可以指定兩個值的和，就像前面的程式片斷。
準備放置到來源控制項
在拖曳作業開始後，當滑鼠經過任何一個控制項時，Visual Basic會在該控制項產生 OLEDragOver 事件。這個事件會接收除了來源物件所設定的 DataObject 及 Effect，還有滑鼠座標及按鈕狀態。程式依據這些資料，把 Effect 參數設定為其可以執行的動作之一，以便確定當使用者將來源物件拖放到元件上時該執行哪個動作。這個值可以是 0-vbDropEffectNone、1-vbDropEffectCopy、2-vbDropEffectMove或是3-vbDropEffectScroll (指目標控制項會捲動自己的內容，例如，當滑鼠在ListBox 控制項上的scrollbar時)。 State 參數代表滑鼠正要進入或是離開控制項，可以是底下的值0-vbEnter、1-vbLeave 及2-vbOver。
Private Sub lstWords_OLEDragOver(Data As DataObject, Effect As Long, _
Button As Integer, Shift As Integer, X As Single, Y As Single, _
State As Integer)
If Data.GetFormat(vbCFText) Then
Effect = Effect And vbDropEffectCopy
Else
Effect = vbDropEffectNone
End If
' As a demonstration, change the background of this ListBox when
' the mouse is over it.
If State = vbLeave Then
' Restore background color on exit.
lstWords.BackColor = vbWindowBackground
ElseIf Effect <> 0 And State = vbEnter Then
' Change background color on entry.
lstWords.BackColor = vbYellow
End If
End Sub
目標控制項必須檢查自己是否支援DataObject 物件所包含的資料型態。這個動作藉由呼叫 DataObject 的 GetFormat 方法來達成，就像上面的程式片斷。另外您必須知道 Effect 參數是一個位元欄位(bit-field)的型態。
Effect = Effect And vbDropEffectCopy
在前面的例子，若來源控制項不支援Copy動作，陳述式 Effect=Effect And vbDropEffectCopy將會把Effect 設為0。剛開始，您可能認為警告是太過度了，因為您知道RichTextBox控制項支援Copy的動作。但是您必須記住的是，當您要讓lstWords控制項能使用拖放作業，它有可能在拖放中，接收到各種可能的來源，不管是從它本身所屬的應用程式或是外面的應用程式，因此，您必須隨時準備應付各種可能的情況。
在來源控制項中，當 OLEDragOver 事件發生後緊跟著發生OLEGiveFeedback 事件。在這個事件中，來源控制項能知道目標控制項所選擇的動作，並可以改變滑鼠游標：
Private Sub lstWords_OLEGiveFeedback(Effect As Long, _
DefaultCursors As Boolean)
' If effect is Copy, use a custom cursor.
If Effect = vbDropEffectCopy Then
DefaultCursors = False
Screen.MousePointer = vbCustom
' imgCopy is an Image control that stores a custom icon.
Screen.MouseIcon = imgCopy.Picture
Else
DefaultCursors = True
End If
End Sub
若您要使用不同的滑鼠游標，必須將 DefaultCursors 參數設為False。當您不需理會游標的形狀時，並不需要實作 OLEGiveFeedback 事件。
放下資料
當使用者在目標控制項放開滑鼠按鍵時，會在目標控制項產生 OLEDragDrop 事件。除了 State 參數外，這個事件接收的參數跟在 OLEDragOver 事件中一樣。在這個情況中，Effect 參數的意義有些不同， 現在它代表目標控制項所決定的動作。
Private Sub lstWords_OLEDragDrop(Data As DataObject, Effect As Long, _
Button As Integer, Shift As Integer, X As Single, Y As Single)
' Restore the correct background color.
lstWords.BackColor = vbWindowBackground
' Select Copy action if possible, otherwise select Move.
If Effect And vbDropEffectCopy Then
Effect = vbDropEffectCopy
ElseIf Effect And vbDropEffectMove Then
Effect = vbDropEffectMove
End If
' In either case, ask for the data - only plain text is supported.
Dim text As String
text = Data.GetData(vbCFText)
' Code for processing the text and loading the list of unique
' words in the lstWords listbox (omitted)...
End Sub
緊接著 OLEDragDrop 事件後，會在來源控制項產生 OLECompleteDrag 事件。您必須在這個事件中撰寫程式碼：當搬移動作時(vbDropEffectMove)，您必須把來源控制項中的反白區刪除，或是還原在拖放作業中控制項所被更改的外觀：
Private Sub rtfText_OLECompleteDrag(Effect As Long)
If Effect = vbDropEffectMove Then
' If this was a Move operation, delete the highlighted text.
rtfText.SelText = ""
Else
' If it was a Copy command, just clear the selection.
rtfText.SelLength = 0
End If
End Sub
在需要時載入資料
當來源控制項支援很多的型態，在 OLEStartDrag 事件發生時，把這些型態資料一次都載入到DataObject 物件，並不是很有效率的解決辦法。很幸運地，Visual Basic提供了另一種方法，在拖曳作業開始時，您只要指定來源控制項將會支援哪些型態，來取代把來源資料載入到DataObject 物件中。
假使拖放作業未被取消，目標控制項最後會呼叫DataObject的 GetData 方法去取得相對所需型態的資料，此時，Visual Basic會在來源控制項發生 OLESetData 事件：
Private Sub rtfText_OLESetData(Data As RichTextLib.DataObject, _
DataFormat As Integer)
' This event fires only when the target control invokes the
' Data(tm)s GetData method.
If DataFormat = vbCFText Then
If rtfText.SelLength Then
Data.SetData rtfText.SelText, vbCFText
Else
Data.SetData rtfText.text, vbCFText
End If
ElseIf DataFormat = vbCFRTF Then
If rtfText.SelLength Then
Data.SetData rtfText.SelRTF, vbCFRTF
Else
Data.SetData rtfText.TextRTF, vbCFRTF
End If
End If
End Sub
但需注意的是，在拖放作業開始，若您把資料傳入 SetData 第一個參數時，並不會發生OLESetData事件。
拖放檔案
就像您所知道的，Windows檔案總管( Windows Explorer) 可以提供檔案名稱的拖放，而很多視窗應用程式可以在檔案總管中當作開始拖曳作業的目標。在這一節，我們將告訴您如何實作這兩個功能－可以當作拖放檔案的來源或是目標的程式。
要完成這個功能的關鍵，就是DataObject的 File 屬性。若需要將您的應用程式當作檔案拖放作業的目標，則必須檢查DataObject物件是否有vbCFFiles格式的資料，然後利用迴圈從檔案集合中讀取檔案名稱進來。舉例來說您可以用底下的程式來讀取拖放到ListBox控制項的檔案名稱：
If Data.GetFormat(vbCFFiles) Then
For i = 1 To Data.Files.Count
lstFiles.AddItem Data.Files(i)
Next
End If
當然，您也可以開啟這個檔案並且顯示它。在圖9-21的範例程式，實作了上述的功能。
| 圖9-21 上層的視窗展示從Windows 檔案總管拖來的AutoDrop.vbp檔案內容 |
而下層的視窗展示從檔案對話方塊所拖來的檔案名稱。
要建立一個可當作檔案拖放來源的應用程式也不困難。您只須把檔案加入到檔案集合中，並且設定為vbCFFiles型態。請記得，目標物件需要檔案集合中存放的是檔案名稱以及完整的檔案路徑。底下的程式告訴您如何把FileListBox控制項當作拖曳作業的來源：
Private Sub File1_OLEStartDrag(Data As DataObject, AllowedEffects As Long)
Dim i As Integer, path As String
path = File1.path & IIf(Right$(File1.path, 1) <> "\", "\", "")
' Add all selected files to the Data.Files collection.
Data.Files.Clear
For i = 0 To File1.ListCount - 1
If File1.Selected(i) Then
Data.Files.Add path & File1.List(i)
End If
Next
If Data.Files.Count Then
' Only if we actually added files
Data.SetData , vbCFFiles
AllowedEffects = vbDropEffectCopy
End If
End Sub
使用自訂的格式
實際上OLE拖放機制可發揮比筆者所示範過更具彈性的程式，它也可支援自訂的格式。舉例來說，您可能需要一個表單能顯示發票、訂單或是客戶的資料，而您希望具有讓使用者可從其他表單拖曳這些資料的能力。使用自訂的格式也可以輕鬆的讓您在不同的應用程式實體中轉換資訊，而同時避免掉不小心將資料放到其他的程式中。使用這個方法，您可以在應用程式間搬移機密性的資料，而不用考慮被未授權使用者獲取的危險。
要使用自訂格式的第一步驟，就是先在Windows中註冊，您可以呼叫RegisterClipboardFormat API函式來達成。每一個使用到自訂格式資料的應用程式都必須要有這個步驟。Windows保證當第一次呼叫並傳入自訂格式名稱(如下面程式中的 PersonalData)給這個函式時，會傳回一個唯一(unique)的整數值，而隨後利用這個格式名稱當參數來呼叫這個API函式時會傳回同樣的值，甚至從不同的應用程式中呼叫這個函式傳回的值也是一樣的。
Private Declare Function RegisterClipboardFormat Lib "user32" _
Alias "RegisterClipboardFormatA" (ByVal lpString As String) As Integer
Dim CustomFormat As Integer
Private Sub Form_Load()
CustomFormat = RegisterClipboardFormat("PersonalData")
End Sub
此時， 您可將資料用CustomFormat 識別字存起來，恰好跟標準格式如vbCFText 或 vbCFBitmap做法相同。唯一不同的是，自訂資料格式在傳送到DataObject.SetData 方法前，必須先載入到Byte陣列。圖9-22的示範程式使用這個技巧在兩個表單間搬移及複製資料：
' Code in the source application
Private Sub imgDrag_OLESetData(Data As DataObject, DataFormat As Integer)
Dim i As Integer, text As String, bytes() As Byte
' Build a long string made up of field contents.
For i = 0 To txtField.UBound
If i > 0 Then text = text & vbNullChar
text = text & txtField(i)
Next
' Move to a byte array, and then assign it to DataObject.
bytes() = text
Data.SetData bytes(), CustomFormat
End Sub
| 圖9-22 您可以在不同表單，甚至在不同的應用程式實體間搬移自訂格式的資料，而不用擔心把機密資料不小心放到其他的地方。 |
目標表單必須取出 Byte陣列，將它們還原成原來的字串，並且放到各自的欄位中：
' Code in the target application
Private Sub imgDrag_OLEDragDrop(Data As DataObject, Effect As Long, _
Button As Integer, Shift As Integer, X As Single, Y As Single)
Dim bytes() As Byte, text() As String, i As Integer
bytes() = Data.GetData(CustomFormat)
' Retrieve individual values, and then assign them to fields.
text() = Split(CStr(bytes), vbNullChar)
For i = 0 To txtField.UBound
txtField(i) = text(i)
Next
End Sub
您可以瀏覽在，隨書光碟中的原始程式碼，取得更多關於這項技巧的資訊。
現在您已掌握了有關SDI及MDI表單、對話方塊、OLE拖放的技巧，並更深入瞭解較複雜的Visual Basic外部ActiveX控制項做好了準備。接下來的三章將探討這些外部ActiveX控制項。